bcelを使ってバイトコードを読む - 自分の仕事を憎むには人生は余りにも短い

そろそろバイトコードを読むお年頃になったので年初めにBCELを使って少し読んでみました。
BECLってのはジャカルタのバイトコード操作ライブラリ。こんなものも揃っているなんて便利な世の中です。
DOMAIN ERROR

まずここから一式をDLしてサンプルを真似しながら解析するクラスを作る。あとは「java listclass -code TestBcel」てなかんじでさくっと実行。実行できたら気合いで読む！

まずは初歩

Stringを返すだけのGetterの場合

ソース

    public String getA () {
        return "Gara";
    }

バイトコード

public String getA()
Code(max_stack = 1, max_locals = 1, code_length = 3)
0:    ldc               "Gara" (16)      「Gara」をコンスタントプールに積む
2:    areturn                            オブジェクトを返値としてreturnする

ふむふむ。文字の生成して返却すると。そのまんまだね

変数を使ってみる。

    public String getA () {
        String aa = "Gara";
        return aa;
    }

public String getA()
Code(max_stack = 1, max_locals = 2, code_length = 5)
0:    ldc               "Gara" (16)      「Gara」をコンスタントプールに積む
2:    astore_1                           オブジェクトを1番目のローカル変数に格納。
3:    aload_1                            1番目のローカル変数からオブジェクトを取り出してスタックに積む
4:    areturn                            オブジェクトを返値としてreturnする

なるほど確かにさっきのに比べてローカル変数がちゃんと使われている。

Objectを返す場合

    public Date getB () {
        return new Date();
    }

public java.util.Date getB()
Code(max_stack = 2, max_locals = 1, code_length = 8)
0:    new               <java.util.Date> (22)            オブジェクトを生成して
3:    dup                                                トップスタックアイテムの値をコピーして更にスタックの上に積む((次にinvokeすると消えちゃうからコピーが必要))
4:    invokespecial     java.util.Date.<init> ()V (24)   インスタンス初期化メソッドの呼び出し
7:    areturn                                            オブジェクト返却

なるほど。バイトコードを見るとクラスがNEWされてからコンストラクタが呼ばれるまでに差が有るのが見える。*1

ちょっとがんばる

読めるようになってきたんで調子乗ってみた

    public void doAction() throws Exception {
        String a = "Pentasa";              １
        String b = "Gara";                 ２
        
        if (b.equals(a)) {                 ３
            System.out.println(b);         ４
        } else {                           ５
            a = null;                      ６ 
        }
        
        if (a == null) {                   ７
            throw new Exception();         ８
        }
    }

public void doAction()
                throws java.lang.Exception
Code(max_stack = 2, max_locals = 3, code_length = 39)
0:    ldc               "Pentasa" (31)        １さっきと同じでコンスタントプール
2:    astore_1                                １ローカル変数に格納
3:    ldc               "Gara" (16)           ２
5:    astore_2                                ２
6:    aload_2                                 ３メソッド呼び出す前にスタックから取り出し
7:    aload_1                                 ３
8:    invokevirtual     java.lang.String.equals (Ljava/lang/Object;)Z (33)
                                              ３メソッド呼び出し
11:   ifeq              #24                   ３スタックの値が0なら#24に飛ぶ((おおおおお！IFってこんなになってたのか！))
14:   getstatic         java.lang.System.out Ljava/io/PrintStream; (39)
                                              ４Staticなクラスを取得する
17:   aload_2                                 ４変数呼び出し
18:   invokevirtual     java.io.PrintStream.println (Ljava/lang/String;)V (45)
                                              ４画面に出力
21:   goto              #26                   ５ELSE句なのでGOTOで#26まで飛ぶ
24:   aconst_null                             ６スタックにNULLを積む
25:   astore_1                                ６
26:   aload_1                                 ７
27:   ifnonnull         #38                   ７コードは「a == null」だが最適化されたのかNotNULLで飛んでいる
30:   new               <java.lang.Exception> (29)
                                              ８オブジェクトNewして
33:   dup                                     ８コピーして
34:   invokespecial     java.lang.Exception.<init> ()V (51)
                                              ８コンストラクタ呼び出し
37:   athrow                                  ８スローする
38:   return                                  終わり

なるほど！IFってこんな風に内部はgotoで実現されているのか。

さらに調子に乗ってシンクロしてみた

    public void doAction2() throws Exception {
        String b = "Gara";                  １
        synchronized (b) {                  ２
            b = "SIN";                      ３
        }                                   ４
        b = "END";                          ５
    }

public void doAction2()
                throws java.lang.Exception
Code(max_stack = 2, max_locals = 3, code_length = 19)
0:    ldc               "Gara" (16)         １
2:    astore_1                              １
3:    aload_1                               １
4:    dup                                   ２
5:    astore_2                              ２
6:    monitorenter                          ２ロック取得！！！
7:    ldc               "SIN" (54)          ３
9:    astore_1                              ３
10:   aload_2                               ３
11:   monitorexit                           ４ロック解放！！！
12:   goto              #18                 ４正常終了時
15:   aload_2                               ４エクセプションハンドラー部分
16:   monitorexit                           ４例外時に解放
17:   athrow                                ４
18:   ldc               "END" (56)          ５
20:   astore_1
21:   return

Exception handler(s) =
From    To      Handler Type
7       12      15      <Any exception>(0)
15      17      15      <Any exception>(0)

シンクロの場合暗黙的に例外時の処理が追加されている。最初なんで追加されているのかわからなかった。